Copilot Commands

Copilot commands interact with GitHub copilot. There are also commands for Codeium and Continue

Inline chat / refactoring / code generation

There are some commands to interact with the inline chat, leveraging Cursorless targets:

Command	Description	Example
"pilot change <target>"	selects target and opens inline chat to enable typing instructions for how Copilot should change the target.	"pilot change funk air"
"pilot change <target> to <phrase>"	tells Copilot to apply the instructions in <phrase> to the target.	"pilot change funk air to remove arguments".
"pilot test <target>"	Asks copilot to generate a test for the target.	"pilot test funk air"
"pilot doc <target>"	Asks copilot to generate documentation for the target.	"pilot doc funk air"
"pilot fix <target>"	Tells copilot to fix the target.	"pilot fix funk air"
"pilot fix <target> to <phrase>"	Tells copilot to fix the target using the instructions in <phrase>.	"pilot fix funk air to remove warnings"
"pilot make <phrase>"	Tells copilot to generate code using the instructions in <phrase>, at the current cursor position.	"pilot make a function that returns the sum of two numbers"

Chat sidebar

There are some commands to interact with the chat sidebar:

Command	Description	Example
"pilot chat"	opens chat to enable typing
"pilot chat hello world"	opens chat, types “hello world” and hits enter
"pilot bring <ordinal>"	inserts nth code block in most recent chat response into your editor at cursor position	"pilot bring first", "pilot bring last", "pilot bring second last"
"pilot copy <ordinal>"	copies nth code block in most recent chat response	"pilot copy first"
"pilot bring <ordinal> <destination>"	inserts nth code block in most recent chat response into your editor at Cursorless destination	"pilot bring first after state air", "pilot bring first to line air"
"pilot bring first to funk"	replaces function containing your cursor with first code block in most recent chat response

Copilot command source

copilot.talon

app: vscode
not tag: user.codeium
-
pilot jest: user.vscode("editor.action.inlineSuggest.trigger")
pilot next: user.vscode("editor.action.inlineSuggest.showNext")
pilot (previous | last): user.vscode("editor.action.inlineSuggest.showPrevious")
pilot yes: user.vscode("editor.action.inlineSuggest.commit")
pilot yes word: user.vscode("editor.action.inlineSuggest.acceptNextWord")
pilot nope: user.vscode("editor.action.inlineSuggest.undo")
pilot cancel: user.vscode("editor.action.inlineSuggest.hide")
pilot block last: user.vscode("workbench.action.chat.previousCodeBlock")
pilot block next: user.vscode("workbench.action.chat.nextCodeBlock")
pilot new file <user.cursorless_ordinal_or_last>:
    user.copilot_focus_code_block(cursorless_ordinal_or_last)
    user.vscode("workbench.action.chat.insertIntoNewFile")
pilot copy <user.cursorless_ordinal_or_last>:
    user.copilot_focus_code_block(cursorless_ordinal_or_last)
    edit.copy()
pilot bring <user.cursorless_ordinal_or_last>:
    user.copilot_bring_code_block(cursorless_ordinal_or_last)
pilot bring <user.cursorless_ordinal_or_last> {user.makeshift_destination} <user.cursorless_target>:
    user.cursorless_command(makeshift_destination, cursorless_target)
    user.copilot_bring_code_block(cursorless_ordinal_or_last)
pilot chat [<user.prose>]$: user.copilot_chat(prose or "")
pilot {user.copilot_slash_command} <user.cursorless_target> [to <user.prose>]$:
    user.cursorless_command("setSelection", cursorless_target)
    user.copilot_inline_chat(copilot_slash_command or "", prose or "")
pilot make [<user.prose>]: user.copilot_inline_chat("", prose or "")